Hydrogen polarizability

PHYS 7230, Spring 2019, Prof. Gondolo

Laguerre polynomials

Gradshteyn-Ryzhik

(Subscript[L, n]^m)(x) = LaguerreL[n,m,x]

GR 8.970.1 	(Subscript[L, n]^m)(x)=(1/(n!))(e^x)(x^(-m))((d^n)/(dx^n))((e^(-x))(x^(m+n)))

GR 8.972.1 	 (Subscript[L, n]^m)(x)=(({{n+m}, {n}}))  Φ(-n,α+1;x)

Abramowitz-Stegun

(Subscript[L, n]^((m)))(x) = LaguerreL[n,m,x]

AS 13.6.27 	U(-n,α+1,x)=(((-1))^n)n! (Subscript[L, n]^((α)))(x)

AS 22.2.12 	(Subscript[L, n]^((m)))(x)=((((-1))^n)/(n!))(x^n)+...

AS 22.5.17 	(Subscript[L, n]^((m)))(x)=(((-1))^m)((d^m)/(dx^m))[(Subscript[L, n+m])(x)]

AS 22.11.6 	(Subscript[L, n]^((m)))(x)=(1/(n!))(e^x)(x^(-m))((d^n)/(dx^n))((e^(-x))(x^(m+n)))

AS 22.11.6 	(Subscript[L, n])(x)=(1/(n!))(e^x)((d^n)/(dx^n))((e^(-x))(x^n))

ASLaguerreL[n_,m_,x_]:=Expand[(1/(n!))Exp[x](x^(-m))D[Exp[-x](x^(m+n)),{x,n}]]

Do[Print[Table[Expand[ASLaguerreL[n,m,x]-LaguerreL[n,m,x]],{n,0,4}]],{m,0,2}]

Griffiths

(Subscript[L, n])(x) = n! LaguerreL[n,m,x]

(Subscript[L, n]^m)(x) = (n+m)! LaguerreL[n,m,x]

Gri 4.88 	(Subscript[L, n])(x)=(e^x)((d^n)/(dx^n))((e^(-x))(x^n))

Gri 4.87 	(Subscript[L, n]^m)(x)=(((-1))^m)((d^m)/(dx^m))[(Subscript[L, n+m])(x)]

GriLaguerreL[n_,x_]:=Expand[Exp[x]D[Exp[-x](x^n),{x,n}]]
GriLaguerreL[n_,m_,x_]:=Expand[(((-1))^m)D[GriLaguerreL[n+m,x],{x,m}]]

GriTableIndices={{0,0},{1,0},{2,0},{0,1},{1,1},{2,1},{0,2},{1,2},{2,2},{0,3},{1,3},{2,3}};
Do[Print[(Subscript["L", n]),"=",GriLaguerreL[n,x]],{n,0,6}]
Map[Print[(Subscript["L", n]^m),"=",GriLaguerreL[#[[1]],#[[2]],x]]&,GriTableIndices];

Do[Print[Table[Expand[GriLaguerreL[n,m,x]-(n+m)!LaguerreL[n,m,x]],{n,0,4}]],{m,0,2}]

Sakurai and Sakurai-Napolitano

(Subscript[L, n]^m)(x)=(((-1))^m)n!LaguerreL[n-m,m,x]

Sak B.6.4  	(Subscript[L, n]^m)(x)=((d^m)/(dx^m))[(Subscript[L, n])(x)]

Sak B.6.5  	(Subscript[L, n])(x)=(e^x)((d^n)/(dx^n))((e^(-x))(x^n))

SakLaguerreL[n_,m_,x_]:=Expand[D[Exp[x]D[Exp[-x](x^n),{x,n}],{x,m}]]

Do[Print[Table[Expand[SakLaguerreL[n,m,x]-(((-1))^m)n!LaguerreL[n-m,m,x]],{m,0,n}]],{n,0,4}]

Landau-Lifshitz

(Subscript[L, n]^m)(x)=(((-1))^m)n!LaguerreL[n-m,m,x]

LL d.13 	(Subscript[L, n]^m)(x)=((n!)/((n-m)!))(e^x)((d^n)/(dx^n))((e^(-x))(x^(n-m)))    (0≤m≤n)

LL after d.13 	(Subscript[L, n])(x)=(e^x)((d^n)/(dx^n))((e^(-x))(x^n))

LLLaguerreL[n_,m_,x_]:=Expand[((n!)/((n-m)!))Exp[x]D[Exp[-x](x^(n-m)),{x,n}]]

Do[Print[Table[Expand[LLLaguerreL[n,m,x]-(((-1))^m)n!LaguerreL[n-m,m,x]],{m,0,n}]],{n,0,4}]

Radial wave functions

(Subscript[R, nl])(r) = ((Subscript[a, 0])^(-3/2))(Subscript[(OverTilde[R]), nl])(x)
r=(Subscript[a, 0])x

r=((n (Subscript[a, 0])ρ)/2)
ρ=((2x)/n)

R[n_,l_,x_]=Sqrt[(2/n)^3(n-l-1)!/(2n(n+l)!)] Exp[-ρ/2]ρ^l LaguerreL[n-l-1,2l+1,ρ]/.{ρ->2x/n}

R[1,0,x]

R[2,0,x]

Table[Table[Integrate[(x^2)((R[n,l,x])^2),{x,0,Infinity}],{l,0,n-1}],{n,1,3}]

Simplify[R[n,1,x]/.{(n+1)!->(n+1)n(n-1)(n-2)!},{n>1}]

(Subscript[⟨2p, 0])|z|2s⟩

⟨210|z|200⟩=∫ dr (r^2)dΩ (Subscript[ψ, 210]^( * ))(r,θ,φ)z (Subscript[ψ, 200])(r,θ,φ )
                             = ∫ dr (r^2)dΩ (Subscript[R, 21])(r) (Subscript[Y, 10]^( * ))(θ,φ)z (Subscript[R, 20])(r) (Subscript[Y, 00])(θ,φ )
                             = ∫ dr (r^3)dΩ (Subscript[R, 21])(r) (Subscript[Y, 10]^( * ))(θ,φ)(Sqrt[((4π)/3)]) (Subscript[Y, 10])(θ,φ)(Subscript[R, 20])(r) (1/(Sqrt[4π]))
                             = (1/(Sqrt[3]))∫ dr (r^3)dΩ (Subscript[R, 21])(r) (Subscript[Y, 10]^( * ))(θ,φ) (Subscript[Y, 10])(θ,φ)(Subscript[R, 20])(r) 
                             = (1/(Sqrt[3]))∫ dr (r^3) (Subscript[R, 21])(r) (Subscript[R, 20])(r) 
                             = (Subscript[a, 0])(1/(Sqrt[3]))(∫_0^∞) dx (x^3) (Subscript[(OverTilde[R]), 21])(x) (Subscript[(OverTilde[R]), 20])(x) 
                             = -3 (Subscript[a, 0])

(1/(Sqrt[3]))Integrate[R[2,1,x]R[2,0,x](x^3),{x,0,Infinity}]

(Subscript[⟨np, 0])|z|1s⟩

⟨n10|z|100⟩=∫ dr (r^2)dΩ (Subscript[ψ, n10]^( * ))(r,θ,φ)z (Subscript[ψ, 100])(r,θ,φ )
                             = ∫ dr (r^2)dΩ (Subscript[R, n1])(r) (Subscript[Y, 10]^( * ))(θ,φ)z (Subscript[R, 10])(r) (Subscript[Y, 00])(θ,φ )
                             = ∫ dr (r^3)dΩ (Subscript[R, n1])(r) (Subscript[Y, 10]^( * ))(θ,φ)(Sqrt[((4π)/3)]) (Subscript[Y, 10])(θ,φ)(Subscript[R, 10])(r) (1/(Sqrt[4π]))
                             = (1/(Sqrt[3]))∫ dr (r^3)dΩ (Subscript[R, n1])(r) (Subscript[Y, 10]^( * ))(θ,φ) (Subscript[Y, 10])(θ,φ)(Subscript[R, 10])(r) 
                             = (1/(Sqrt[3]))∫ dr (r^3) (Subscript[R, n1])(r) (Subscript[R, 10])(r) 
                             =(Subscript[a, 0])(1/(Sqrt[3]))(∫_0^∞) dx (x^3) (Subscript[(OverTilde[R]), n1])(x) (Subscript[(OverTilde[R]), 10])(x)

(Subscript[⟨2p, 0])|z|1s⟩

⟨210|z|100⟩=(Sqrt[2])((2^7)/(3^5)) (Subscript[a, 0])

(1/(Sqrt[3]))Integrate[(x^3)R[2,1,x]R[1,0,x],{x,0,Infinity}]
FactorInteger[%/Sqrt[2]]
(Sqrt[2])((2^7)/(3^5))

(Subscript[⟨3p, 0])|z|1s⟩

⟨310|z|100⟩=(Sqrt[2])((3^3)/(2^7)) (Subscript[a, 0])

(1/(Sqrt[3]))Integrate[R[3,1,x]R[1,0,x](x^3),{x,0,Infinity}]
FactorInteger[%/Sqrt[2]]
(Sqrt[2])((3^3)/(2^7))

(Subscript[⟨4p, 0])|z|1s⟩

⟨410|z|100⟩=(Sqrt[5])(((2^11)3)/(5^7)) (Subscript[a, 0])

(1/(Sqrt[3]))Integrate[R[4,1,x]R[1,0,x](x^3),{x,0,Infinity}]
FactorInteger[%/Sqrt[5]]
(Sqrt[5])(((2^11)3)/(5^7))

(Subscript[⟨np, 0])|z|1s⟩

expr=Simplify[(1/(Sqrt[3]))(x^3)R[n,1,x]R[1,0,x]/.{(n+1)!->(n+1)n(n-1)(n-2)!},n>1]

expr1=Simplify[(n/2)expr/.{x->n t/2},n>1]

Cn=Apply[Times,Select[Apply[List,expr1],FreeQ[#,t]&]]
expr2=expr1/Cn

Cn=FullSimplify[Cn,{n∈Integers,n>1}]

(Subscript[C, n])= ((n^(3/2))/(4 (Sqrt[3]) (Sqrt[-1+(n^2)])))

(Subscript[C, n])(∫_0^∞)(e^(-(((n+1) t)/2))) (t^4) (Subscript[L, n-2]^3)(t) dt

GR 7.414.7    (∫_0^∞) (e^(-s t))(t^β)(Subscript[L, n]^α)(t) dt = ((Γ(β+1)Γ(α+n+1))/(n! Γ(α+1)))(s^(-β-1))F(-n,β+1;α+1;(1/s)) with Re β>-1, Re s>0

GR 7.414.7 with s->((n+1)/2), β->4, n->n-2, α->3

expr3=FullSimplify[((β! (α+n)!)/(n! α!))(s^(-β-1))Hypergeometric2F1[-n,β+1,α+1,1/s]/.{s->((n+1)/2),β->4,n->n-2,α->3},{n∈Integers,n>1}]

bn=FullSimplify[Cn expr3,{n∈Integers,n>1}]

b[n_]=(((2^4)n)/(Sqrt[3]))((((n/((n^2)-1))))^(5/2))(((((n-1)/(n+1))))^n)

Table[b[n],{n,2,4}]

printPrimeFactor[{a_,b_}]:=((ToString[a])^b)
toPrimeFactors[k_]:=Block[{tmp=Apply[List,k]},Apply[Times,Flatten[{Map[printPrimeFactor,FactorInteger[tmp[[1]]]],tmp[[2]]}]]]

Table[toPrimeFactors[b[n]],{n,2,20}]

f[n_]=FullSimplify[((4 ((b[n])^2))/(1-(1/(n^2)))),{n∈Integers,n>1}]

Series[f[n],{n,Infinity,3}]

kk=10;
ffkk=Sum[f[n],{n,2,kk-1}];ff[k_]:=ffkk+f[kk]/2+NIntegrate[f[n],{n,kk,k}]
ffsum=ffkk+f[kk]/2+NIntegrate[f[n],{n,kk,Infinity}]

Show[
ListPlot[Accumulate[Table[N[f[n]],{n,2,200}]]],
Plot[ff[k],{k,kk,200},PlotStyle->Orange],
Plot[ffsum,{k,2,200},PlotStyle->Black],
AxesLabel->{"n","(∑_(n ≥ 2))((4 (Subscript[b, n]^2))/(1 - (1/(n^2))))"},PlotRange->All
]